嵌入式开发者社区

标题: FIR例程 [打印本页]
作者: 70010x    时间: 2016-12-12 15:42
标题: FIR例程
[attach]1683[/attach]
如图函数的原型在哪里，我找到了几个接近的，但是没有找到该函数原型。请赐教
作者: IRONMAN    时间: 2016-12-12 17:14
那可能就没有
作者: 电子微创意    时间: 2016-12-13 08:26
在dsplib安装目录下
作者: 70010x    时间: 2016-12-14 15:10
电子微创意 发表于 2016-12-13 08:26
在dsplib安装目录下

我就是在这个文件夹里找的，没有找到这个函数，希望您能给我一个详细的路径，帮我解决这个问题。
作者: 70010x    时间: 2016-12-14 15:11
IRONMAN 发表于 2016-12-12 17:14
那可能就没有

没有的话函数怎么可以执行？
作者: 电子微创意    时间: 2016-12-15 21:42
70010x 发表于 2016-12-14 15:10
我就是在这个文件夹里找的，没有找到这个函数，希望您能给我一个详细的路径，帮我解决这个问题。 ...

比如我安装目录
C:\ti\c674x-dsplib_1_03_00_01\src\DSPF_sp_fir_r2 目录下的
这是TI经过优化的代码。DSPF_sp_fir_r2.asm就是源码
作者: 希望缄默    时间: 2016-12-17 21:45
电子微创意 发表于 2016-12-15 21:42
比如我安装目录
C:\ti\c674x-dsplib_1_03_00_01\src\DSPF_sp_fir_r2 目录下的
这是TI经过优化的代码。DSP ...

这是正确答案啊
C:\ti\dsplib_c674x_3_4_0_0\packages\ti\dsplib\src\DSPF_sp_fir_r2\c674
其中DSPF_sp_fir_r2_cn.c 自然 C 语言代码
  1. #pragma CODE_SECTION(DSPF_sp_fir_r2_cn, ".text:ansi");

  3. #include "DSPF_sp_fir_r2_cn.h"

  5. void DSPF_sp_fir_r2_cn(const float *x, const float *h,
  6.     float *y, const int nh, const int ny)
  7. {
  8.     int i, j;
  9.     float sum;

  11.     for (j = 0; j < ny; j++)
  12.     {
  13.         sum = 0;

  15.         // note: h coeffs given in reverse order: { h[nh-1], h[nh-2], ..., h[0] }
  16.         for (i = 0; i < nh; i++)
  17.             sum += x[i + j] * h[i];
  18.         
  19.         y[j] = sum;
  20.     }
  21. }
复制代码
DSPF_sp_fir_r2_opt.c 优化 C 语言代码
  1. #pragma CODE_SECTION(DSPF_sp_fir_r2_opt, ".text:intrinsic");

  3. void DSPF_sp_fir_r2_opt(const float * x, const float * h,
  4.     float *restrict y, const int nh, const int ny)
  5. {
  6.     int i, j;
  7.     float sum1, sum2;

  9.     _nassert((int)x % 8 == 0);
  10.     _nassert((int)h % 8 == 0);
  11.     _nassert(nh >= 4);
  12.     _nassert(nh % 2 == 0);
  13.     _nassert(ny >= 2);
  14.     _nassert(ny % 2 == 0);
  15.    
  16.     #pragma MUST_ITERATE(1,,)
  17.     for (j = 0; j < ny; j += 2)
  18.     {
  19.         sum1 = 0;
  20.         sum2 = 0;

  22.         #pragma MUST_ITERATE(2,,)
  23.         for (i = 0; i < nh; i += 2)
  24.         {
  25.             sum1 += x[i + j] * h[i];
  26.             sum2 += x[i + j + 1] * h[i];
  27.             
  28.             sum1 += x[i + j + 1] * h[i + 1];
  29.             sum2 += x[i + j + 2] * h[i + 1];
  30.         }

  32.         // store the results
  33.         y[j]     = sum1;
  34.         y[j + 1] = sum2;
  35.     }
  36. }
复制代码
DSPF_sp_fir_r2.s 汇编优化代码
  1. * ======================================================================= *
  2. * DSPF_sp_fir_r2.asm -- FIR R2 Filter                                     *
  3. *                 Legacy ASM Implementation from C67x DSPLIB              *
  4. *                                                                         *
  5. * Rev 0.0.2                                                               *
  6. *                                                                         *
  7. * ----------------------------------------------------------------------- *
  8. *            Copyright (c) 2009 Texas Instruments, Incorporated.          *
  9. *                           All Rights Reserved.                          *
  10. * ======================================================================= *


  13. * ======================================================================== *
  14. * ======================================================================== *

  16.         .sect ".text:optimized"
  17.         .if __TI_EABI__
  18.         .asg  DSPF_sp_fir_r2, _DSPF_sp_fir_r2
  19.         .endif               
  20.                
  21.         .global _DSPF_sp_fir_r2
  22. _DSPF_sp_fir_r2:

  24. * ======================================================================== *
  25. * ======================================================================== *

  27.                .asg   B15,     B_SP
  28.                .asg   A0,      A_SP
  29.                .asg   A4,      A_x
  30.                .asg   A5,      A_x_ptr
  31.                .asg   B4,      B_h
  32.                .asg   B5,      B_h_ptr
  33.                .asg   A8,      A_CSR_str
  34.                .asg   B0,      B_CSR_gie
  35.                .asg   A8,      A_nr
  36.                .asg   B2,      B_nr
  37.                .asg   A6,      A_r
  38.                .asg   A6,      A_nh
  39.                .asg   B6,      B_r
  40.                .asg   B6,      B_nh
  41.                .asg   B10,     B_x0
  42.                .asg   B10,     B_x2
  43.                .asg   B10,     B_x20
  44.                .asg   B11,     B_x1
  45.                .asg   B11,     B_x3
  46.                .asg   B11,     B_x31
  47.                .asg   B12,     B_x42
  48.                .asg   B12,     B_x4
  49.                .asg   B12,     B_x_2
  50.                .asg   A10,     A_h0
  51.                .asg   A11,     A_h1
  52.                .asg   A7,      A_prod
  53.                .asg   B7,      B_prod
  54.                .asg   A9,      A_sum
  55.                .asg   B9,      B_sum
  56.                .asg   A2,      A_zero
  57.                .asg   B1,      B_zero
  58.                .asg   A5,      A_zero1
  59.                .asg   B5,      B_zero1
  60.                .asg   B14,     B_prod1
  61.                .asg   A3,      A_prod2
  62.                .asg   A12,     A_prod3
  63.                .asg   A0,      A_prod4
  64.                .asg   A12,     A_x20
  65.                .asg   A12,     A_x0
  66.                .asg   A12,     A_x2
  67.                .asg   A13,     A_x31
  68.                .asg   A13,     A_x1
  69.                .asg   A13,     A_x3
  70.                .asg   A12,     A_sum_4
  71.                .asg   B13,     B_h_1
  72.                .asg   B14,     B_h1
  73.                .asg   A2,      A_ictr
  74.                .asg   A1,      A_RSTflg
  75.                .asg   A1,      A_h_t
  76.                .asg   A1,      A_h_1t
  77.                .asg   B8,      B_MULT4
  78.                .asg   B2,      B_MULflg
  79.                .asg   B0,      B_MULT2
  80.                .asg   B0,      B_STRflg
  81.                .asg   B1,      B_nreq2
  82.                .asg   A5,      A_sum_t
  83.                .asg   B5,      B_sum_t
  84.                .asg   B14,     B_x
  85.                


  88.              LDDW  .D1T2 *A_x,      B_x1:B_x0             ; load x[i+j+1]:x[i+j]
  89. ||           SUBAW .D2   B_SP,      11,         B_SP      ; Save stack space
  90. ||           AND   .L2X  A_nr,      0x3,        B_MULflg  ; find out multiple of 4
  91. ||           MVC   .S2   CSR,       B_CSR_gie             ; Get CSR
  92. ||           MV    .L1   A_x,       A_x_ptr               ; Set x_ptr
  93. ||           MV    .S1X  B_h,       A_h_t                 ; Set temporary h_ptr

  95.              LDW   .D1T1 *+A_h_t[3],A_h_1t                ; load h[i+3] to remove cross path
  96. ||[B_MULflg] SUB   .S1   A_nr,      2,          A_nr      ; make counter multiple of 4
  97. ||           MVK   .S2   0,         B_MULT4               ; flag for multiple of 4
  98. ||           STW   .D2T2 B_x,       *+B_SP[5]             ; store B14
  99. ||           MV    .L2   B_h,       B_h_ptr               ; Set h_ptr
  100. ||           MV    .L1X  B_SP,      A_SP                  ; Copy stack pointer
  101.             
  102.              STW   .D2T1 A_h0,      *+B_SP[1]             ; Sore A10
  103. ||           STW   .D1T2 B_x20,     *+A_SP[6]             ; Store B10
  104. ||[!B_MULflg]MVK   .S2   1,         B_MULT4               ; flag for multiple of 4
  105. ||           MV    .L2X  A_nr,      B_nr                  ; copy nr
  106.   
  107.              STW   .D2T1 A_h1,      *+B_SP[2]             ; Store A11
  108. ||           STW   .D1T2 B_x31,     *+A_SP[7]             ; Store B11
  109. ||           MV    .S1X  B_CSR_gie, A_CSR_str             ; Store CSR  
  110. ||           AND   .S2   B_CSR_gie, -2,         B_CSR_gie ; Disable GIE
  111.                
  112.              STW   .D2T1 A_x20,     *+B_SP[3]             ; Store A12
  113. ||           STW   .D1T2 B_x42,     *+A_SP[8]             ; Store B12
  114. ||           MV    .L1X  B_nh,      A_nh                  ; Change side of nh
  115. ||           MV    .L2X  A_r,       B_r                   ; Change side of r
  116.   
  117.              STW   .D2T1 A_x31,     *+B_SP[4]             ; Store A13
  118. ||           STW   .D1T2 B_h_1,     *+A_SP[9]             ; Store B13
  119. ||           MVC   .S2   B_CSR_gie, CSR                   ; Disable interrupt
  120. ||           ZERO  .L2   B_nreq2                          ; flag for checking if nr=2

  122. ; -------------------------------------------------------------
  123.                
  124.              LDDW  .D2T1 *B_h++,    A_h1:A_h0             ; load h[i+1]:h[i]
  125. ||[B_nr]     ADDAD .D1   A_x_ptr,   2,          A_x_ptr   ; if nr!=2 update x_ptr
  126. ||[!B_nr]    MVK   .S2   1,         B_nreq2               ; Set flag for nr=2
  127. ||[!B_nr]    SUB   .L2   1,         B_MULT4,    B_MULT4   ; Invert Mult4 flag if nr=2

  129.              LDW   .D1T2 *A_x[2],   B_x_2                 ; load x[i+j+2]
  130. ||[!B_nr]    MVK   .S2   4,         B_nr                  ; load 4 in counter if NR=2
  131. ||           MV    .L2X  A_h_1t,    B_h_1                 ; Get h[i+3]
  132.                
  133.              LDDW  .D1T2 *++A_x,    B_x31:B_x20           ; load x[i+j+3(1)]:x[i+j+2(0)]
  134. ||           MV    .L2X  A_x_ptr,   B_x                   ; Set x_ptr for B side         
  135.                
  136.              LDW   .D1T2 *A_x[2],   B_x42                 ; load x[i+j+2(4)]
  137. ||           SUB   .S1   A_nh,      2,          A_ictr    ; Set inner loop ctr
  138. ||           ZERO  .L1   A_prod                           ; Initialise prod
  139. ||           ZERO  .L2   B_prod                           ; Initialise prod
  140. ||           B     .S2   ILOOP                            ; Branch to inner loop
  141.                
  142.              LDDW  .D2T1 *B_h++,    A_h1:A_h0             ; load h[i+1]:h[i]
  143. ||           SUB   .S1   A_nh,      2,          A_RSTflg  ; Set reset flag
  144. ||           ZERO  .L2   B_sum                            ; Initialise accumulator
  145. ||           ZERO  .L1   A_sum                            ; Initialise accumulator
  146. ||           MVK   .S2   0,         B_STRflg              ; Reset store flag

  148. ILOOP:
  149.   [B_STRflg] STW   .D2T1 A_sum_4,   *B_r++                ; Store sum7
  150. ||[!A_RSTflg]LDW   .D1T2 *A_x[2],   B_x42                 ; load x[i+j+2(4)]
  151. ||           MPYSP .M1X  A_h0,      B_x0,       A_prod    ; h[i] * x[i+j]
  152. ||           MPYSP .M2X  A_h1,      B_x1,       B_prod    ; h[i+1] * x[i+j+1]
  153. ||           ADDSP .L1   A_sum,     A_prod,     A_sum     ; sum1 += h[i] * x[i+j]
  154. ||           ADDSP .L2   B_sum,     B_prod,     B_sum     ; sum2 += h[i+1] * x[i+j+1]
  155. ||[!A_RSTflg]MVK   .S1   6,         A_RSTflg              ; Reset reset flag
  156. ||           MVK   .S2   0,         B_STRflg              ; Reset store flag

  158.              LDDW  .D1T2 *++A_x,    B_x31:B_x20           ; load x[i+j+3(1)]:x[i+j+2(0)]
  159. ||[!A_ictr]  LDDW  .D2T1 *++B_x,    A_x31:A_x20           ; load x[i+j+3(1)]:x[i+j+2(0)]
  160. ||           MPYSP .M1X  A_h0,      B_x1,       A_prod    ; h[i] * x[i+j+1]
  161. ||           MPYSP .M2X  A_h1,      B_x_2,      B_prod    ; h[i+1] * x[i+j+2]         
  162. ||           ADDSP .L1   A_sum,     A_prod,     A_sum     ; sum3 += h[i] * x[i+j+1]
  163. ||           ADDSP .L2   B_sum,     B_prod,     B_sum     ; sum4 += h[i+1] * x[i+j+2]
  164. ||[A_RSTflg] SUB   .S1   A_RSTflg,  2,          A_RSTflg  ; Update reset flag

  166.              LDW   .D1T2 *A_x[2],   B_x42                 ; load x[i+j+2(4)]
  167. ||[!A_RSTflg]MV    .D2   B_h_ptr,   B_h                   ; Set h pointer
  168. ||           MPYSP .M1X  A_h0,      B_x2,       A_prod    ; h[i] * x[i+j+2]           
  169. ||           MPYSP .M2X  A_h1,      B_x3,       B_prod    ; h[i+1] * x[i+j+3]
  170. ||           ADDSP .L1   A_sum,     A_prod,     A_sum     ; sum5 += h[i] * x[i+j+2]
  171. ||           ADDSP .L2   B_sum,     B_prod,     B_sum     ; sum6 += h[i+1] * x[i+j+3]
  172. ||[A_ictr]   B     .S2   ILOOP                            ; Branch to inner loop
  173. ||[A_ictr]   SUB   .S1   A_ictr,    2,          A_ictr    ; Update inner loop counter

  175.              LDDW  .D2T1 *B_h++,    A_h1:A_h0             ; load h[i+1]:h[i]
  176. ||[!A_RSTflg]LDDW  .D1T2 *A_x_ptr,  B_x1:B_x0             ; load x[i+j+1]:x[i+j+0]               
  177. ||           MPYSP .M1X  A_h0,      B_x3,       A_prod    ; h[i] * x[i+j+3]
  178. ||           MPYSP .M2X  A_h1,      B_x4,       B_prod    ; h[i+1] * x[i+j+4]
  179. ||           ADDSP .L1   A_sum,     A_prod,     A_sum     ; sum7 += h[i] * x[i+j+3]
  180. ||           ADDSP .L2   B_sum,     B_prod,     B_sum     ; sum8 += h[i+1] * x[i+j+4]
  181. ||[!A_RSTflg]MV    .S1   A_x_ptr,   A_x                   ; Set x pointer

  183. ; ------------------------------------------------------------

  185.              LDW   .D2T2 *-B_h[1],  B_h1                  ; load h[i+5]
  186. ||           MPYSP .M1   A_h0,      A_x0,       A_prod    ; h[i] * x[i+j]
  187. ||           MPYSP .M2   B_h_1,     B_x1,       B_prod    ; h[i+1] * x[i+j+1]  
  188. ||           ADDSP .L1   A_zero,    A_prod,     A_sum     ; sum1 = h[i] * x[i+j]
  189. ||           ADDSP .L2X  A_sum,     B_sum,      B_sum     ; sum2 = sum1 + sum2
  190. ||           MV    .S2   B_prod,    B_prod1               ; sum2 = h[i+1] * x[i+j+1]  
  191. ||           ADDAD .D1   A_x_ptr,   2,          A_x_ptr   ; Update x_ptr

  193.              LDDW  .D1T2 *++A_x,    B_x31:B_x20           ; load x[i+j+3(1)]:x[i+j+2(0)]
  194. ||[B_nr]     SUB   .D2   B_nr,      4,          B_nr      ; Update outer loop counter               
  195. ||           MPYSP .M1   A_h0,      A_x1,       A_prod    ; h[i] * x[i+j+1]
  196. ||           MPYSP .M2   B_h_1,     B_x_2,      B_prod    ; h[i+1] * x[i+j+2]               
  197. ||           ADDSP .L2X  A_zero,    B_prod,     B_sum     ; sum4 = h[i+1] * x[i+j+2]
  198. ||           ADDSP .L1X  A_sum,     B_sum,      A_sum     ; sum3 = sum3 + sum4
  199. ||           MV    .S1   A_prod,    A_prod2               ; sum3 = h[i] * x[i+j+1]
  200. ||[!B_nreq2] ZERO  .S2   B_zero                           ; Zero for pseudo move

  202.              LDW   .D1T2 *A_x[2],   B_x42                 ; load x[i+j+2(4)]
  203. ||           MPYSP .M1   A_h0,      A_x2,       A_prod    ; h[i] * x[i+j+2]               
  204. ||           MPYSP .M2   B_h_1,     B_x3,       B_prod    ; h[i+1] * x[i+j+3]
  205. ||           ADDSP .L2   B_zero,    B_prod,     B_sum     ; sum6 = h[i+1] * x[i+j+3]
  206. ||           ADDSP .L1X  A_sum,     B_sum,      A_sum     ; sum5 = sum5 + sum6
  207. ||           MV    .S1   A_prod,    A_prod3               ; sum5 = h[i] * x[i+j+2]
  208. ||[B_nr]     B     .S2   ILOOP
  209. ||           ADD   .D2   B_MULT4,   B_nr,       B_MULT2   ; If last it.¬ mult4 then 0 else 1

  211.              LDDW  .D2T1 *B_h++,    A_h1:A_h0             ; load h[i+1]:h[i]
  212. ||           MPYSP .M1   A_h0,      A_x3,       A_prod    ; h[i] * x[i+j+3]
  213. ||           MPYSP .M2   B_h_1,     B_x4,       B_prod    ; h[i+1] * x[i+j+4]
  214. ||           ADDSP .L2   B_zero,    B_prod,     B_sum     ; sum8 = h[i+1] * x[i+j+4]
  215. ||           ADDSP .L1X  A_sum,     B_sum,      A_sum_4   ; sum7 = sum7 + sum8
  216. ||           MV    .D1   A_prod,    A_prod4               ; sum7 = h[i] * x[i+j+3]
  217. ||[!B_MULT2] B     .S1   MULT2
  218.                
  219. ; ------------------------------------------------------------

  221.              STW   .D2T2 B_sum,     *B_r++                ; Store sum2
  222. ||           MPYSP .M1X  A_h0,      B_x0,       A_prod    ; h[i] * x[i+j]
  223. ||           MPYSP .M2X  A_h1,      B_x1,       B_prod    ; h[i+1] * x[i+j+1]   
  224. ||           ADDSP .L1   A_sum,     A_prod,     A_sum     ; sum1 += h[i] * x[i+j]
  225. ||           ADDSP .L2   B_prod1,   B_prod,     B_sum     ; sum2 += h[i+1] * x[i+j+1]
  226. ||           SUB   .S1   A_nh,      8,          A_ictr    ; Update inner loop ctr

  228.              STW   .D2T1 A_sum,     *B_r++                ; Store sum3      
  229. ||           LDDW  .D1T2 *++A_x,    B_x31:B_x20           ; load x[i+j+3(1)]:x[i+j+2(0)]   
  230. ||           MPYSP .M1X  A_h0,      B_x1,       A_prod    ; h[i] * x[i+j+1]
  231. ||           MPYSP .M2   B_h1,      B_x_2,      B_prod    ; h[i+1] * x[i+j+2]                  
  232. ||           ADDSP .L1   A_prod2,   A_prod,     A_sum     ; sum3 += h[i] * x[i+j+1]
  233. ||           ADDSP .L2   B_sum,     B_prod,     B_sum     ; sum4 += h[i+1] * x[i+j+2]
  234. ||           SUB   .S1   A_nh,      8,          A_RSTflg  ; Update reset flag
  235. ||           MV    .S2X  A_x_ptr,   B_x                   ; Set x pointer for B side

  237.   [!B_nreq2] STW   .D2T1 A_sum,     *B_r++                ; Store sum5
  238. ||           LDW   .D1T2 *A_x[2],   B_x42                 ; load x[i+j+2(4)]
  239. ||           MPYSP .M1X  A_h0,      B_x2,       A_prod    ; h[i] * x[i+j+2]               
  240. ||           MPYSP .M2X  A_h1,      B_x3,       B_prod    ; h[i+1] * x[i+j+3]
  241. ||           ADDSP .L1   A_prod3,   A_prod,     A_sum     ; sum5 += h[i] * x[i+j+2]
  242. ||           ADDSP .L2   B_sum,     B_prod,     B_sum     ; sum6 += h[i+1] * x[i+j+3]
  243. ||[B_nr]     B     .S1   ILOOP                            ; Branch to inner loop
  244. ||[!A_RSTflg]MV    .S2   B_h_ptr,   B_h                   ; Set h pointer

  246.              LDDW  .D2T1 *B_h++,    A_h1:A_h0             ; load h[i+1]:h[i]
  247. ||[!A_RSTflg]LDDW  .D1T2 *A_x_ptr,  B_x1:B_x0             ; load x[i+j+1]:x[i+j+0]
  248. ||           MPYSP .M1X  A_h0,      B_x3,       A_prod    ; h[i] * x[i+j+3]
  249. ||           MPYSP .M2X  A_h1,      B_x4,       B_prod    ; h[i+1] * x[i+j+4]
  250. ||           ADDSP .L1   A_prod4,   A_prod,     A_sum     ; sum7 += h[i] * x[i+j+3]
  251. ||           ADDSP .L2   B_sum,     B_prod,     B_sum     ; sum8 += h[i+1] * x[i+j+4]   
  252. ||[!A_RSTflg]MV    .S1   A_x_ptr,   A_x                   ; Set x pointer

  254. ; -------------------------------------------------------------
  255.   [!B_nreq2] STW   .D2T1 A_sum_4,   *B_r++                ; Store sum2
  256. ||           MPYSP .M1X  A_h0,      B_x0,       A_prod    ; h[i] * x[i+j]
  257. ||           MPYSP .M2X  A_h1,      B_x1,       B_prod    ; h[i+1] * x[i+j+1]   
  258. ||           ADDSP .L1   A_sum,     A_prod,     A_sum     ; sum1 += h[i] * x[i+j]
  259. ||           ADDSP .L2   B_sum,     B_prod,     B_sum     ; sum2 += h[i+1] * x[i+j+1]
  260. ||[!B_MULT2] B     .S2   LOOP                             ; Jump to inner loop of MULT2         
  261. ; -------------------------------------------------------------     
  262.          
  263. END:              
  264.              MVC   .S2X  A_CSR_str, CSR                   ; Enable Interrupts
  265. ||           MV    .S1X  B_SP,      A_SP                  ; Copy stach pointer
  266.         
  267.              LDW   .D1T1 *+A_SP[1], A_h0                  ; Load A10   
  268. ||           LDW   .D2T2 *+B_SP[6], B_x20                 ; Load B10
  269.                
  270.              LDW   .D1T1 *+A_SP[2], A_h1                  ; Load A11
  271. ||           LDW   .D2T2 *+B_SP[7], B_x31                 ; Load B11
  272.                
  273.              LDW   .D1T1 *+A_SP[3], A_x20                 ; Load A12
  274. ||           LDW   .D2T2 *+B_SP[8], B_x42                 ; Load B12

  276.              LDW   .D1T1 *+A_SP[4], A_x31                 ; Load A13
  277. ||           LDW   .D2T2 *+B_SP[9], B_h_1                 ; Load B13
  278. ||           B     .S2   B3                               ; Branch out of the function
  279.         
  280.              LDW   .D2T2 *+B_SP[5], B_x                   ; Load B14
  281.         
  282.              ADDAW .D2   B_SP,      11,         B_SP      ; Restore stack space   
  283.         
  284.              NOP         3                                 
  285.            
  286. ; -------------------------------------------------------------           
  287. MULT2:         
  288.   [A_ictr]   LDDW  .D1T2 *++A_x,    B_x1:B_x0             ; load x[i+j+1]:x[i+j+0]
  289. ||[A_ictr]   LDDW  .D2T1 *B_h++,    A_h1:A_h0             ; load h[i+1]:h[i]
  290. ||           MPYSP .M1X  A_h0,      B_x1,       A_prod    ; h[i] * x[i+j+1]
  291. ||           MPYSP .M2X  A_h1,      B_x_2,      B_prod    ; h[i+1] * x[i+j+2]
  292. ||           ADDSP .L1   A_sum,     A_prod,     A_sum     ; sum3 += h[i] * x[i+j+1]
  293. ||           ADDSP .L2   B_sum,     B_prod,     B_sum     ; sum4 += h[i+1] * x[i+j+2]
  294. ||           ZERO  .S1   A_zero1                          ; Zero for pseudo move
  295. ||           ZERO  .S2   B_zero1                          ; Zero for pseudo move

  297.   [A_ictr]   LDW   .D1T2 *A_x[2],   B_x_2                 ; load x[i+j+2]                 
  298. ||           ADDSP .L1   A_zero1,   A_zero1,    A_sum     ; Zero sum1
  299. ||           ADDSP .L2   B_zero1,   B_zero1,    B_sum     ; Zero sum2
  300. ||           MPYSP .M1   A_prod,    A_zero1,    A_prod    ; Zero prod1
  301. ||           MPYSP .M2   B_prod,    B_zero1,    B_prod    ; Zero prod2
  302. ||[A_ictr]   SUB   .S1   A_ictr,    2,          A_ictr    ; Update counter
  303. ||[A_ictr]   B     .S2   LOOP                             ; Branch to loop
  304.                
  305.   [A_ictr]   LDDW  .D1T2 *++A_x,    B_x1:B_x0             ; load x[i+j+1]:x[i+j+0]   
  306. ||           LDDW  .D2T1 *B_h++,    A_h1:A_h0             ; load h[i+1]:h[i]
  307. ||           ADDSP .L1   A_zero1,   A_zero1,    A_sum     ; Zero sum3
  308. ||           ADDSP .L2   B_zero1,   B_zero1,    B_sum     ; Zero sum4
  309. ||           MPYSP .M1   A_prod,    A_zero1,    A_prod    ; Zero prod3
  310. ||           MPYSP .M2   B_prod,    B_zero1,    B_prod    ; Zero prod4

  312. ; --------------------------------------------------------------


  315. LOOP:
  316.   [A_ictr]   LDW   .D1T2 *A_x[2],   B_x_2                 ; load x[i+j+2]
  317. ||           MPYSP .M1X  A_h0,      B_x0,       A_prod    ; h[i] * x[i+j]
  318. ||           MPYSP .M2X  A_h1,      B_x1,       B_prod    ; h[i+1] * x[i+j+1]   
  319. ||           ADDSP .L1   A_sum,     A_prod,     A_sum     ; sum1 += h[i] * x[i+j]
  320. ||           ADDSP .L2   B_sum,     B_prod,     B_sum     ; sum2 += h[i+1] * x[i+j+1]
  321. ||[A_ictr]   SUB   .S1   A_ictr,    2,          A_ictr    ; Update counter
  322. ||[A_ictr]   B     .S2   LOOP                             ; Branch to loop

  324.   [A_ictr]   LDDW  .D1T2 *++A_x,    B_x1:B_x0             ; load x[i+j+1]:x[i+j+0]   
  325. ||[A_ictr]   LDDW  .D2T1 *B_h++,    A_h1:A_h0             ; load h[i+1]:h[i]
  326. ||           MPYSP .M1X  A_h0,      B_x1,       A_prod    ; h[i] * x[i+j+1]
  327. ||           MPYSP .M2X  A_h1,      B_x_2,      B_prod    ; h[i+1] * x[i+j+2]  
  328. ||           ADDSP .L1   A_sum,     A_prod,     A_sum     ; sum3 += h[i] * x[i+j+1]
  329. ||           ADDSP .L2   B_sum,     B_prod,     B_sum     ; sum4 += h[i+1] * x[i+j+2]

  331.              ADDSP .L1X  A_sum,     B_sum,      A_sum     ; sum1 = sum1 + sum3
  332.                
  333.              ADDSP .L2X  A_sum,     B_sum,      B_sum     ; sum3 = sum3 + sum4
  334.                
  335.              ADDSP .L1X  A_sum,     B_sum,      A_sum_t   ; sum1'= sum1 + sum2
  336.                
  337.              ADDSP .L2X  A_sum,     B_sum,      B_sum_t   ; sum3'= sum3 + sum4
  338.                
  339.              NOP         2
  340.                
  341.              ADDSP .L1   A_sum,     A_sum_t,    A_sum     ; sum1 = sum1 + sum1'
  342. ||           B     .S2   END                              ; branch to end

  344.              ADDSP .L2   B_sum,     B_sum_t,    B_sum     ; sum3 = sum3 + sum3'
  345.                
  346.              NOP         2
  347.                
  348.              STW   .D2T1 A_sum,     *B_r++                ; Store sum1
  349.                
  350.              STW   .D2T2 B_sum,     *B_r++                ; Store sum3
  351. ; -----------------------------------------------------------------------------


  354.                 .end

  356. * ======================================================================= *
  357. *  End of file:  DSPF_sp_fir_r2.asm                                       *
  358. * ----------------------------------------------------------------------- *
  359. *            Copyright (c) 2009 Texas Instruments, Incorporated.          *
  360. *                           All Rights Reserved.                          *
  361. * ======================================================================= *
复制代码


作者: 希望缄默    时间: 2016-12-17 21:47
希望缄默 发表于 2016-12-17 21:45
这是正确答案啊
C:\ti\dsplib_c674x_3_4_0_0\packages\ti\dsplib\src\DSPF_sp_fir_r2\c674
其中DSPF_sp_f ...

例程调用的是汇编函数 即 DSPF_sp_fir_r2
作者: 电子微创意    时间: 2016-12-18 11:09
受益匪浅啊
作者: 70010x    时间: 2016-12-22 10:41
电子微创意 发表于 2016-12-15 21:42
比如我安装目录
C:\ti\c674x-dsplib_1_03_00_01\src\DSPF_sp_fir_r2 目录下的
这是TI经过优化的代码。DSP ...

嗯，谢谢你，理解了~
作者: 70010x    时间: 2016-12-22 10:43
希望缄默 发表于 2016-12-17 21:47
例程调用的是汇编函数 即 DSPF_sp_fir_r2

亲临指导，理解了，哈哈。



欢迎光临 嵌入式开发者社区 (https://www.51ele.net/) Powered by Discuz! X3.4